<!--#Include File="Include/Top_inc.asp"-->
<!--#Include File="Include/Config_inc.asp"-->
<%
'***********************************************************************
'   Application: SelectSurveyASP Advanced v8.1.1
'   Author: Aaron Baril for ClassApps.com
'   Page Description: This is the page that displays the actual survey for
'                     users to take.
'
'   COPYRIGHT NOTICE								
'
'   See attached Software License Agreement
'
'   (c) Copyright 2002 - 2006 by ClassApps.com.  All rights reserved.
'***********************************************************************

%>
<!--#Include File="Include/SurveyUtility_inc.asp"-->
<!--#Include File="Include/Utility_inc.asp"-->
<!--#Include File="Include/adovbs_inc.asp"-->
<!--#Include File="Include/CurrentUser_inc.asp"-->
<!--#Include File="Include/Constants_inc.asp"-->
<!--#Include File="Include/SurveySecurity_inc.asp"-->
<!--#Include File="Include/Collection_inc.asp"-->
<!--#Include File="Include/Encryption_inc.asp"-->
<!--#Include File="Include/SurveyPageCondition_inc.asp"-->
<!--#Include File="Include/SurveyRendering_inc.asp"-->

<%
	Dim strSQL
	Dim lngSurveyID
	Dim rsSurvey
	Dim rsResponseID
	Dim rsTemplate
	Dim rsPage
	Dim rsLastActualPage
	Dim lngQuestionNumber
	Dim flgUpdatingSurvey
	Dim flgUpdateableSurvey
	Dim flgHasStartedSurvey
	Dim flgHasCompletedSurvey
	Dim lngResponseID
	Dim lngActualPageNumber
	Dim lngDisplayPageNumber
	Dim lngPageCount
	Dim strQuestionNumberingFormat
	Dim flgResponseIDFound
	Dim lngItemID
	Dim lngTemplateID
	Dim strEditValue
	Dim strTitle
	Dim strLogoPath
	Dim strLogoAlignment
	Dim strSurveyAlignment
	Dim strDisplayBorderYN
	Dim strBorderColor
	Dim lngBorderWidth
	Dim strProgressFirstColor
	Dim strProgressSecondColor
	Dim strSurveyBackgroundColor
	Dim strPageBackgroundColor
	Dim strHTMLTop
	Dim strHTMLBottom
	Dim strNavigationBackButtonPath
	Dim strNavigationBackLinkText
	Dim strNavigationNextButtonPath
	Dim strNavigationNextLinkText
	Dim strNavigationDoneButtonPath
	Dim strNavigationDoneLinkText
	Dim strNavigationCancelButtonPath
	Dim strNavigationCancelLinkText
	Dim strPageTitle
	Dim strPageIntroduction
	Dim strBackButtonDisplay
	Dim strCancelButtonDisplay
	Dim strCancelButtonRedirectURL
	Dim strButtonPath
	Dim strRedirectURL
	Dim strEncryptedIDs
	Dim lngEmailAddressID
	Dim lngEmailMessageID
	Dim strResponseType
	Dim strTempDate
	Dim strTempValue
	Dim strItemIDValues
		
	'Initialization
	If Len(Request.QueryString("SurveyID")) > 0 Then
		lngSurveyID = DecryptSurveyID(Request.QueryString("SurveyID"))
		
		'The situation where you have both a survey ID and an EID in the querystring comes up when 
		'there is a survey with no answerable questions on the first page
		If Len(Request.QueryString("EID")) > 0 Then
			lngEmailAddressID = GetEncryptedEmailAddressID(Request.QueryString("EID"))
			lngEmailMessageID = GetEncryptedEmailMessageID(Request.QueryString("EID"))
		End If
	Else
		strEncryptedIDs = Request.QueryString("EID")
		lngSurveyID = GetEncryptedSurveyID(strEncryptedIDs)
		lngEmailAddressID = GetEncryptedEmailAddressID(strEncryptedIDs)
		lngEmailMessageID = GetEncryptedEmailMessageID(strEncryptedIDs)
		'Check to make sure that the user has not already responded to this message
		If HasRespondedToMessage(strEncryptedIDs) = True Then
			If HasUserCompletedSurvey(lngSurveyID) = True And IsUpdateableSurvey(lngSurveyID) = False And IsMultipleResponseSurvey(lngSurveyID) = False Then
				Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(GetEncryptedSurveyID(Request.QueryString("EID"))) & "&Reason=" & SUR_ACCESS_DENIED_ALREADY_RESPONDED_TO_MESSAGE
			End If
		End If
	End If

	lngPageCount = GetPageCount(lngSurveyID)
	lngItemID = -1
	Set rsSurvey = Server.CreateObject("ADODB.Recordset")
	Set rsResponseID = Server.CreateObject("ADODB.Recordset")
	Set rsTemplate = Server.CreateObject("ADODB.Recordset")
	Set rsPage = Server.CreateObject("ADODB.Recordset")
	Set rsLastActualPage = Server.CreateObject("ADODB.Recordset")

	'Make sure that the survey ID is a valid survey. This is an important check because it's possible that 
	'the survey was deleted since the time it was deployed.
	If IsValidSurveyID(lngSurveyID) = False Then
		Response.Redirect "AccessDenied.asp?Reason=" & SUR_ACCESS_DENIED_INVALID_SURVEY_ID
	End If
	
	'If the survey is in manual response entry mode, this is a straight insert
	If IsManualResponseEntryMode(lngSurveyID) = True Then
		If IsUserOwnerOrAdmin(lngSurveyID) = True Then
			strResponseType = SUR_RESPONSE_TYPE_MANUAL
			flgUpdatingSurvey = False
			
			'If the response ID is in the querystring, the user has already started this survey.  Otherwise, the user
			'is just starting this survey, so put them on the first page.
			If Len(Request.QueryString("ResponseID")) > 0 Then
				lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
				lngActualPageNumber = Request.QueryString("ActualPageNumber")
				lngResponseID = Request.QueryString("ResponseID")
			Else
				If Request.QueryString("DisplayPageNumber") <> "" And Request.QueryString("DisplayPageNumber") <> "1" Then
					lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
					lngActualPageNumber = Request.QueryString("ActualPageNumber")
				Else
					lngDisplayPageNumber = 1
					lngActualPageNumber = 1
				End If
			End If
		Else
			Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_MANUAL_ENTRY_MODE
		End If
	Else
		'The user must be logged in before attempting to take a survey, unless the survey allows
		'anonymous access
		If IsLoggedIn() = False And IsSurveyAnonymous(lngSurveyID) = False Then
			'If the SurveyID or EID is in the querystring, be sure to add it to the page before redirecting
			If Len(strEncryptedIDs) > 0 Then
				Response.Redirect "Login.asp?EID=" & strEncryptedIDs
			ElseIf Len(lngSurveyID) > 0 Then
				Response.Redirect "Login.asp?SurveyID=" & Request.QueryString("SurveyID")
			Else
				Response.Redirect "Login.asp"
			End If
		End If

		'Make sure the survey is "LIVE" based on both its status and its start and end dates, if specified, before a 
		'user takes it.  If it's not "LIVE", redirect.
		If IsSurveyLive(lngSurveyID) = False Then
			Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_NOT_LIVE
		End If

		'Check to see if the survey is being updated by a survey owner or an admin.  If so, extract the Response ID, and set
		'the page numbers appropriately
		If Request.Form("AdminOrOwnerEditResponse") = SUR_BOOLEAN_POSITIVE_DISPLAY Or Request.QueryString("Edit") = SUR_BOOLEAN_POSITIVE_DISPLAY Then
			If Request.Form("AdminOrOwnerEditResponse") = SUR_BOOLEAN_POSITIVE_DISPLAY Then
				lngResponseID = Request.Form("AdminOrOwnerResponseID")
			Else
				lngResponseID = Request.QueryString("ResponseID")
			End If
			flgUpdatingSurvey = True

			'If the display page number is not specified, it's the first page
			If Len(Request.QueryString("DisplayPageNumber")) = 0 Then
				lngDisplayPageNumber = 1
				lngActualPageNumber = 1
			Else
				lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
				lngActualPageNumber = Request.QueryString("ActualPageNumber")
			End If
		Else
			'Look at the session tracking variable to see if the user has already taken this page in the survey.
			If Len(Session(SUR_SESSION_TAKING_SURVEY & lngSurveyID)) > 0 And InStr(Session(SUR_SESSION_TAKING_SURVEY & lngSurveyID), "||Page" & Request.QueryString("ActualPageNumber") & "||") > 0 Then
				flgUpdatingSurvey = True
				lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
				lngActualPageNumber = Request.QueryString("ActualPageNumber")
				lngQuestionNumber = Request.QueryString("QuestionNumber")
			Else
				'If the survey allows multiple responses, then it is not being updated.  Also, if the survey allows multiple responses,
				'make sure that the current user has not reached the maximum response count, if specified
				If IsMultipleResponseSurvey(lngSurveyID) = True Then
					flgUpdatingSurvey = False

					'For multiple response surveys, make sure that the current user has not reached the response count limit
					If IsMaxResponseCountForUserReached(lngSurveyID) = True And Len(Request.QueryString("ResponseID")) = 0 Then
						Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_MAX_RESPONSE_COUNT_PER_USER_EXCEEDED
					End If

					'If the display page number is not specified, it's the first page
					If Len(Request.QueryString("DisplayPageNumber")) = 0 Then
						lngDisplayPageNumber = 1
						lngActualPageNumber = 1
					Else
						lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
						lngActualPageNumber = Request.QueryString("ActualPageNumber")
					End If
				Else 'The survey does not allow multiple responses from a single user, so check to see if a prior response can be updated
					'Update flags indicating a) whether or not the survey is updateable, b) whether or not the current user has
					'already started to take this survey, c) whether or not the current user has completed this survey, and d) whether 
					'or not the current user is updating a survey they've already taken
					flgUpdateableSurvey = IsUpdateableSurvey(lngSurveyID)
					flgHasStartedSurvey = HasUserStartedSurvey(lngSurveyID)
					flgHasCompletedSurvey = HasUserCompletedSurvey(lngSurveyID)

					If flgUpdateableSurvey = True Then
						'For updateable surveys, check to see whether or not the current user has started the survey
						If flgHasStartedSurvey = True Then
							'Since this is an updateable survey and the user has already responded to the survey, check to see
							'if the number of days the survey can be updated has been reached.
							If IsMaxDaysForUpdatedReached(lngSurveyID) = True Then
								Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_MAX_DAYS_FOR_UPDATE_REACHED
							End If
							
							flgUpdatingSurvey = True
						Else
							flgUpdatingSurvey = False
						End If		

						'If the display page number is not specified, it's the first page
						If Len(Request.QueryString("DisplayPageNumber")) = 0 Then
							lngDisplayPageNumber = 1
							lngActualPageNumber = 1
						Else
							lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
							lngActualPageNumber = Request.QueryString("ActualPageNumber")
						End If

						'If the question number is not specified, it's the first question on the first page
						If Len(Request.QueryString("QuestionNumber")) = 0 Then
							lngQuestionNumber = 1
						Else
							lngQuestionNumber = Request.QueryString("QuestionNumber")
						End If
					Else 'The survey is not updateable
						'If the current user has completed the survey, redirect to an error page
						If (flgHasCompletedSurvey = True) Or (flgHasStartedSurvey = True And Len(Session(SUR_SESSION_TAKING_SURVEY & lngSurveyID)) = 0) Then 
							Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_ALREADY_TAKEN
						Else 
							'The survey is not updateable, and the user has not completed it.  If they have started it, they are doing
							'an update.
							If flgHasStartedSurvey = True Then
								flgUpdatingSurvey = True
							Else
								flgUpdatingSurvey = False
							End If		
							
							'Get the response ID for the survey that the user is completing.  There will only be a response ID if
							'the user has previously started this survey.
							strSQL = "SELECT response_id " & _
										"FROM sur_response r " & _
										"WHERE survey_id = " & lngSurveyID
					
							'If the user is anonymous, query using the anonymous id
							If GetUsername() = SUR_ANONYMOUS_USER Then
								strSQL = strSQL & " AND anonymous_id = " & GetAnonymousUserID()
							Else
								strSQL = strSQL & " AND username = " & SQLEncode(GetUsername())
							End If
							rsResponseID.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenDynamic, , adCmdText

							'If the user is updating a survey, at least one record must be returned
							If flgUpdatingSurvey = True Then 
								rsResponseID.MoveFirst
								lngResponseID = rsResponseID("response_id")

								'If the display page number is not specified, this is a user who started the survey earlier, and 
								'is now coming back to complete it
								If Len(Request.QueryString("DisplayPageNumber")) = 0 Then
									'Get the last actual page answered
									strSQL = "SELECT max(page_number) As LastActualPage " & _
										"FROM sur_survey_to_item_mapping m, sur_response_answer ra " & _
										"WHERE m.item_id = ra.item_id " & _
										"AND response_id = " & lngResponseID & _
										" AND survey_id = " & lngSurveyID
									rsLastActualPage.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenDynamic, , adCmdText
									rsLastActualPage.MoveFirst
									lngActualPageNumber = rsLastActualPage("LastActualPage")
									rsLastActualPage.Close
									Set rsLastActualPage = Nothing
								
									'Get the page to display next
									lngDisplayPageNumber = GetNextPageInSurvey(lngSurveyID, lngResponseID, lngActualPageNumber)
								Else
									'This is a user who just took the prior page in the survey
									lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
									lngActualPageNumber = Request.QueryString("ActualPageNumber")
								End If
							Else 'The user has not yet started this survey
								'If the display page number is not specified, it's the first page
								If Len(Request.QueryString("DisplayPageNumber")) = 0 Then
									lngDisplayPageNumber = 1
									lngActualPageNumber = 1
								Else
									lngDisplayPageNumber = Request.QueryString("DisplayPageNumber")
									lngActualPageNumber = Request.QueryString("ActualPageNumber")
								End If
							End If

							'If the question number is not specified, it's the first question on the first page
							If Len(Request.QueryString("QuestionNumber")) = 0 Then
								lngQuestionNumber = 1
							Else
								lngQuestionNumber = Request.QueryString("QuestionNumber")
							End If

							'Close the recordset
							rsResponseID.Close
						End If 'If flgHasCompletedSurvey = True Then 
					End If 'If flgUpdateableSurvey = True Then
				End If 'If IsMultipleResponseSurvey(lngSurveyID) = True Then

				'Make sure that the maximum response count has not been reached.  Check the HasStartedSurvey flag because if the
				'the user has already started this survey, it's OK for them to be the last response (the response count has been
				'reached).
				If IsMaxResponseCountReached(lngSurveyID) = True And Len(Request.QueryString("ResponseID")) = 0 Then
					Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_MAX_RESPONSE_COUNT_EXCEEDED
				End If

				'If the ResponseID has been passed in, save it in a local variable
				If Len(Request.QueryString("ResponseID")) > 0 Then
					lngResponseID = Request.QueryString("ResponseID")
				End If
			End If
		End If
		
		'Set the response type
		If IsLoggedIn() = True Then
			strResponseType = SUR_RESPONSE_TYPE_LOGGED_IN
		Else
			strResponseType = SUR_RESPONSE_TYPE_ANONYMOUS
		End If
	End If
	
	'If this is the first page of the survey, check to make sure that the IP address is in a valid range
	If IsIPAddressInRange(lngSurveyID) = False Then
		Response.Redirect "TakeSurveyError.asp?SurveyID=" & EncryptSurveyID(lngSurveyID) & "&Reason=" & SUR_ACCESS_DENIED_IP_ADDRESS_OUT_OF_RANGE
	End If
	
	'If the user is updating the survey, query for all the items on the current page along with the previous answers
	If flgUpdatingSurvey = True Then
		strSQL = "SELECT title, survey_language, template_id, i.item_type_id As item_type_id, " & _
					"required_yn, email_address_yn, it.item_type_name As ItemType, other_yn, database_dsn, " & _
					"m.order_number As order_number, maximum_length, i.item_id As item_id, random_answer_order_yn, " & _
					"display_format, image_path, image_height, image_width, image_alignment, minimum_value, " & _
					"maximum_value, answer_total, minimum_number_responses, maximum_number_responses, row_text_width, other_display_type, " & _
					"default_value, subitem_count, back_button_display, cancel_button_display, cancel_button_redirect_url, " & _
					"r.response_id As ResponseID, ra.answer_id As AnswerID, page_numbering_format, " & _
					"question_numbering_format, item_text, ra.other_text As OtherTextAnswer, " & _
					"i.other_text As OtherTextQuestion, ra.answer_text As AnswerText, database_sql, item_sub_text " & _
					"FROM sur_response AS r RIGHT JOIN ((((sur_survey AS s RIGHT JOIN sur_survey_to_item_mapping AS m " & _
					"ON s.survey_id = m.survey_id) INNER JOIN sur_item AS i " & _
					"ON m.item_id = i.item_id) INNER JOIN sur_item_type AS it " & _
					"ON i.item_type_id = it.item_type_id) LEFT JOIN sur_response_answer AS ra " & _
					"ON i.item_id = ra.item_id) ON r.response_id = ra.response_id " & _
					"WHERE m.page_number = " & lngActualPageNumber & _
					" AND m.survey_id = " & lngSurveyID
					
		'If the survey is being edited by a survey owner or an admin, we know the response ID, so use it in the query
		If Request.Form("AdminOrOwnerEditResponse") = SUR_BOOLEAN_POSITIVE_DISPLAY Then
			strSQL = strSQL & " AND r.response_id = " & Request.Form("AdminOrOwnerResponseID")
		ElseIf Request.QueryString("Edit") = SUR_BOOLEAN_POSITIVE_DISPLAY And Len(Request.QueryString("ResponseID")) > 0 Then
			strSQL = strSQL & " AND r.response_id = " & Request.QueryString("ResponseID")
		Else
			'If the user is anonymous, query using the anonymous id
			If GetUsername() = SUR_ANONYMOUS_USER Then
				strSQL = strSQL & " AND r.anonymous_id = " & GetAnonymousUserID() & _
						" AND r.response_id = (SELECT MAX(response_id) FROM sur_response WHERE " & _
						" r.anonymous_id = " & GetAnonymousUserID() & _
						" AND survey_id = " & lngSurveyID & ")"
			Else
				strSQL = strSQL & " AND (r.username = " & SQLEncode(GetUsername()) & " OR r.username IS NULL) " & _
						" AND r.response_id = (SELECT MAX(response_id) FROM sur_response WHERE " & _
						"(username = " & SQLEncode(GetUsername()) & " OR username IS NULL) " & _
						"AND survey_id = " & lngSurveyID & ")"
			End If
		End If

		'Complete the SQL statement and execute it
		strSQL = strSQL & " ORDER BY m.order_number"
		rsSurvey.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenDynamic, , adCmdText

		'If the survey is being edited by an admin or owner, we already know the response ID, so there's no need 
		'to search for it.
		If Request.Form("AdminOrOwnerEditResponse") = SUR_BOOLEAN_POSITIVE_DISPLAY Or Request.QueryString("Edit") = SUR_BOOLEAN_POSITIVE_DISPLAY Then
			flgResponseIDFound = True
		Else
			'Check to see if all the response ID's in the recordset are Null.  If so, there were no prior answers for 
			'this page.  Therefore, the user is not updating the current page of the survey, but rather entering it for 
			'the first time.
			flgResponseIDFound = False
			If Not rsSurvey.EOF Then
				rsSurvey.MoveFirst
				Do While Not rsSurvey.EOF
					If IsNull(rsSurvey("ResponseID")) = False Then
						flgResponseIDFound = True
						lngResponseID = rsSurvey("ResponseID")
					End If
					rsSurvey.MoveNext
				Loop
			End If
		End If

		'If a response ID was not found, the user is not updating the survey, but rather is on a page other than the first
		'page of the survey.  Therefore, find out the response ID.
		If flgResponseIDFound = False Then
			'Set the updating flag to false and close the survey recordset
			flgUpdatingSurvey = False
			rsSurvey.Close
			
			'Get the response ID for the survey that the user is completing.  There will only be a response ID if
			'the user has previously started this survey.
			strSQL = "SELECT response_id " & _
						"FROM sur_response r " & _
						"WHERE survey_id = " & lngSurveyID
		
			'If the user is anonymous, query using the anonymous id
			If GetUsername() = SUR_ANONYMOUS_USER Then
				strSQL = strSQL & " AND anonymous_id = " & GetAnonymousUserID()
			Else
				strSQL = strSQL & " AND username = " & SQLEncode(GetUsername())
			End If
			rsResponseID.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenDynamic, , adCmdText
			rsResponseID.MoveFirst
			lngResponseID = rsResponseID("response_id")

			'Clean up
			rsResponseID.Close
			Set rsResponseID = Nothing
		Else 'If a response ID was found, the user is updating the survey, so move back to the beginning of the recordset to render it below
			If Not rsSurvey.EOF Then
				rsSurvey.MoveFirst
			ElseIf Request.Form("AdminOrOwnerEditResponse") = SUR_BOOLEAN_POSITIVE_DISPLAY Or Request.QueryString("Edit") = SUR_BOOLEAN_POSITIVE_DISPLAY Then
				'Set the updating flag to false and close the survey recordset
				flgUpdatingSurvey = False
				rsSurvey.Close
			End If
		End If
	End If

	'The user is not updating the survey.  This means either it's the first time the user has taken the survey, or the 
	'user started the survey, and is now completing it.
	If flgUpdatingSurvey = False Then
		strSQL = "SELECT title, survey_language, template_id, i.item_type_id As item_type_id, " & _
					"required_yn, email_address_yn, it.item_type_name As ItemType, random_answer_order_yn, " & _
					"other_yn, m.order_number As order_number, i.item_id As item_id, database_dsn, " & _
					"display_format, maximum_length, image_path, image_height, image_width, image_alignment, " & _
					"minimum_value, maximum_value, answer_total, minimum_number_responses, maximum_number_responses, " & _
					"row_text_width, subitem_count, page_numbering_format, question_numbering_format, back_button_display, " & _
					"cancel_button_display, cancel_button_redirect_url, default_value, item_text, " & _
					"other_text As OtherTextQuestion, database_sql, item_sub_text, other_display_type " & _
					"FROM sur_survey s, sur_item i, sur_survey_to_item_mapping m, sur_item_type it " & _
					"WHERE i.item_id = m.item_id " & _
					"AND m.page_number = " & lngActualPageNumber & _
					" AND s.survey_id = m.survey_id " & _
					"AND it.item_type_id = i.item_type_id " & _
					"AND m.survey_id = " & lngSurveyID & _
					" ORDER BY m.order_number"
		rsSurvey.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenDynamic, , adCmdText
	End If

	'Get the survey title and template ID for reuse later
	rsSurvey.MoveFirst
	strTitle = rsSurvey("title")
	strBackButtonDisplay = rsSurvey("back_button_display")
	strCancelButtonDisplay = rsSurvey("cancel_button_display")
	strCancelButtonRedirectURL = rsSurvey("cancel_button_redirect_url")
	lngTemplateID = rsSurvey("template_id")
%>
<html lang="<%=rsSurvey("survey_language")%>">
<head>
	<title><%=strTitle%></title>
	<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
	<meta http-equiv="Content-Language" content="it">

</head>


<% 
	'Initialize the question number before generating the JavaScript.
	If Len(Request.QueryString("QuestionNumber")) = 0 Then
		lngQuestionNumber = 1
	Else
		lngQuestionNumber = Request.QueryString("QuestionNumber")
	End If
%>
<script language ="JavaScript" src="ClientInclude/Utility.js"></script>
<script language="JavaScript">

// Dynamically generate client-side script to ensure that the user submits values for 
// all required questions.
function submitCheck()
{
	var flgValueSelected;
	var lngTotalValue = 0;
	var strTemp;
	var strSelectedValues = "";
<%
	rsSurvey.MoveFirst
	Do While Not rsSurvey.EOF
		'Check the item ID to make sure that JavaScript is rendered only one per question
		If lngItemID <> CLng(rsSurvey("item_id")) Then
			Select Case rsSurvey("item_type_id")
				Case SUR_ITEM_HEADING, SUR_ITEM_IMAGE, SUR_ITEM_MESSAGE, SUR_ITEM_HTML, SUR_ITEM_HORIZONTAL_RULE:
					'Nothing to do here
				Case SUR_ITEM_SINGLE_SELECT_DROPDOWN, SUR_ITEM_DATABASE_DROPDOWN:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>				
						if (document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value == "<%=SUR_COMBO_PLEASE_SELECT%>")
						{
							alert("Selezionare un valore per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%					
					End If
				Case SUR_ITEM_CONSTANT_SUM:
%>					
					// Dynamically check that at least one text box has a value
					flgValueSelected = false;
					lngTotalValue = 0;

					if (document.forms['frmSurvey'] != null) 
					{
					    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
					    {
							strTemp = document.forms['frmSurvey'].elements[i].name;
							if (strTemp.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
							{
								strTemp = trim(document.forms['frmSurvey'].elements[i].value);
								if (strTemp.length > 0)
								{
									flgValueSelected = true;
										
									if (isNumeric(trim(document.forms['frmSurvey'].elements[i].value)) == false)
									{
										alert("Assicurarsi che i valori inseriti per la domanda numero <%=lngQuestionNumber%> siano numerici.");
										document.forms['frmSurvey'].elements[i].focus();
										return;
									}
									lngTotalValue = lngTotalValue + Number(document.forms['frmSurvey'].elements[i].value);
								}
							}
					    }
					}
<%
					'If an answer total was specified, regardless of whether or not the question is required, 
					'make sure that the values add up to the desired amount
					If Len(rsSurvey("answer_total")) > 0 Then
%>					
						if (flgValueSelected == true && lngTotalValue != <%=rsSurvey("answer_total")%>)
						{
							alert("The sum of all answers for question number <%=lngQuestionNumber%> must add up to <%=rsSurvey("answer_total")%>.  The current sum is " + lngTotalValue + ".");
							return;
						}
<%					
					ElseIf rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
						'If the question is required, but no total was specified, make sure that the user selected at least one value
%>
						if (flgValueSelected == false)
						{
							alert("Inserisci almeno un valore per la domanda numero <%=lngQuestionNumber%>.");
							return;
						}
<%
					End If
				Case SUR_ITEM_RANKING: 
%>
					flgValueSelected = false;
					strSelectedValues = "";
					
					// Dynamically check that all text boxes have a value
					if (document.forms['frmSurvey'] != null) 
					{
					    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
					    {
							strTemp = document.forms['frmSurvey'].elements[i].name;
							if (strTemp.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
							{
								strTemp = trim(document.forms['frmSurvey'].elements[i].value);
								if (strTemp.length > 0)
								{
									// Set the flag to indicate that a value has been selected
									flgValueSelected = true;
									
									// Make sure the value entered is numeric
									if (isNumeric(trim(document.forms['frmSurvey'].elements[i].value)) == false)
									{
										alert("Assicurarsi che i valori inseriti per la domanda numero <%=lngQuestionNumber%> siano numerici.");
										document.forms['frmSurvey'].elements[i].focus();
										return;
									}

									// Make sure the value entered is not greater than the number of ranking items
									if (Number(document.forms['frmSurvey'].elements[i].value) > <%=rsSurvey("subitem_count")%> || Number(document.forms['frmSurvey'].elements[i].value) <= 0)
									{
										alert("Item rankings must be between 1 and <%=rsSurvey("subitem_count")%>.");
										document.forms['frmSurvey'].elements[i].focus();
										return;
									}

									// Check to see if the value has already been entered
									strTemp = trim(document.forms['frmSurvey'].elements[i].value);
									if (strSelectedValues.indexOf('||' + strTemp + '||') > -1)
									{
										alert("Il valore " + strTemp + " è stato inserito più di una volta.  Ogni valore di punteggio può essere inserito solo una volta.");
										document.forms['frmSurvey'].elements[i].focus();
										return;
									}
										
									// Record the selected values to make sure that the same number is not entered twice
									strSelectedValues = strSelectedValues + '||' + trim(document.forms['frmSurvey'].elements[i].value) + '||'
								}
<%
								'Only need to check if the question is required
								If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>
									else
									{
										alert("Inserire i valori per tutti gli elementi della domanda numero <%=lngQuestionNumber%>.");
										document.forms['frmSurvey'].elements[i].focus();
										return;
									}
<%
								End If
%>									
							}
					    }
					}
<%
				Case SUR_ITEM_SINGLE_SELECT_OPTIONS:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>					
						// Dynamically check that required option button question has been answered
						flgValueSelected = false;

						if (document.forms['frmSurvey'] != null) 
						{
						    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
						    {
								if (document.forms['frmSurvey'].elements[i].name == 'QID<%=rsSurvey("item_id")%>')
								{
									if (document.forms['frmSurvey'].elements[i].checked == true)
									{
										flgValueSelected = true;
									}
								}
						    }
						}

						if (flgValueSelected == false)
						{
							alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
							return;
						}
<%					
					End If
				Case SUR_ITEM_MATRIX_SINGLE_SELECT_OPTIONS:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>					
						var coll = document.forms['frmSurvey'];
						var flgAllRowsSelected = true;

						// Dynamically check that at least one checkbox or option button has been selected
						flgValueSelected = false;

						if (document.forms['frmSurvey'] != null) 
						{
						    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
						    {
								strTemp = coll.elements[i].name;
								if (strTemp.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
								{
									// Check to see if the control is selected
									if (document.forms['frmSurvey'].elements[i].checked == true)
									{
										flgValueSelected = true;
									}

									// If the name of the next element is different, then this is the last item in the row
									if (coll.elements[i + 1].name != strTemp)
									{
										// If an item in this row was selected, simply re-initialize the flag
										if (flgValueSelected == true)
										{
											flgValueSelected = false;
										}
										else
										{
											// If no item was selected in this row, set the global flag for input required.
											flgAllRowsSelected = false;
										}
									}
								}
						    }
						}

						if (flgAllRowsSelected == false)
						{
							alert("Selezionare almeno un elemento per riga nella domanda numero <%=lngQuestionNumber%>.");
							return;
						}
<%					
					End If
				Case SUR_ITEM_MATRIX_MULTISELECT_CHECKBOXES, SUR_ITEM_MATRIX_RATING_SCALE:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>					
						var coll = document.forms['frmSurvey'];

						// Dynamically check that at least one checkbox or option button has been selected
						flgValueSelected = false;

						if (document.forms['frmSurvey'] != null) 
						{
						    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
						    {
								strTemp = coll.elements[i].name;
								if (strTemp.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
								{
									if (document.forms['frmSurvey'].elements[i].checked == true)
									{
										flgValueSelected = true;
									}
								}
						    }
						}

						if (flgValueSelected == false)
						{
							alert("Selezionare almeno una risposta per la domanda numero <%=lngQuestionNumber%>.");
							return;
						}
<%					
					End If
				Case SUR_ITEM_MATRIX_TEXT_BOXES:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>					
						var coll = document.forms['frmSurvey'];

						// Dynamically check that at least one text box as a value entered
						flgValueSelected = false;

						if (document.forms['frmSurvey'] != null) 
						{
						    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
						    {
								strTemp = coll.elements[i].name;
								if (strTemp.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
								{
									strTemp = trim(document.forms['frmSurvey'].elements[i].value);
									if (strTemp.length > 0)
									{
										flgValueSelected = true;
									}
								}
						    }
						}

						if (flgValueSelected == false)
						{
							alert("Inserire un valore per almeno un elemento della domanda numero <%=lngQuestionNumber%>.");
							return;
						}
<%					
					End If
				Case SUR_ITEM_MULTISELECT_CHECKBOXES:
					'Only need to check if the question is required, if the maximum number of responses was specified, or if the 
					'minimum number of responses was specified
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Or Len(rsSurvey("maximum_number_responses")) > 0 Or Len(rsSurvey("minimum_number_responses")) > 0 Then
%>				
						// Count the number of responses to this question
						var coll = document.forms['frmSurvey'];
						var lngNumberSelected = 0;
						var strName;
						if (coll != null) 
						{
						    for (i = 0; i < coll.length; i++) 
						    {
								strName = coll.elements[i].name;
								if (strName.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
								{
									if (coll.elements[i].checked == true)
									{
										lngNumberSelected = lngNumberSelected + 1;
									}
								}
						    }
						}
<%
						'If the question is required make sure that at least one response was selected.
						If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>
							if (lngNumberSelected < 1) 
							{
								alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If

						'If the minimum number of responses was specified, make sure that at 
						'least the minimum number of responses were selected
						If Len(rsSurvey("minimum_number_responses")) > 0 Then
%>
							if (isFirstNumberLarger(<%=rsSurvey("minimum_number_responses")%>, lngNumberSelected) == true) 
							{
								alert("Selezionare almeno <%=rsSurvey("minimum_number_responses")%> <% If CLng(rsSurvey("minimum_number_responses")) = 1 Then Response.Write " valore" Else Response.Write " valori" End If %> per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If

						'If a maximum number of responses was specified, make sure that no more than the maximum number of 
						'responses were selected
						If Len(rsSurvey("maximum_number_responses")) > 0 Then
%>
							if (isFirstNumberLarger(lngNumberSelected, <%=rsSurvey("maximum_number_responses")%>) == true) 
							{
								alert("Non è possibile selezionare più di <%=rsSurvey("maximum_number_responses")%> <% If CLng(rsSurvey("maximum_number_responses")) = 1 Then Response.Write " valore" Else Response.Write " valori" End If %> per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If
					End If
				Case SUR_ITEM_OPEN_ENDED_ONE_OR_MORE_LINES:
					'Only need to check if the question is required, if the maximum number of responses was specified, or if the 
					'minimum number of responses was specified
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Or Len(rsSurvey("maximum_number_responses")) > 0 Or Len(rsSurvey("minimum_number_responses")) > 0 Then
%>				
						// Count the number of responses to this question
						var coll = document.forms['frmSurvey'];
						var lngNumberEntered = 0;
						var strName;
						if (coll != null) 
						{
						    for (i = 0; i < coll.length; i++) 
						    {
								strName = coll.elements[i].name;
								if (strName.indexOf('QID<%=rsSurvey("item_id")%>') > -1)
								{
									strTemp = trim(coll.elements[i].value);
									if (strTemp.length > 0)
									{
										lngNumberEntered = lngNumberEntered + 1;
									}
								}
						    }
						}
<%
						'If the question is required make sure that at least one response was selected.
						If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>
							if (lngNumberEntered < 1) 
							{
								alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If

						'If the minimum number of responses was specified, make sure that at 
						'least the minimum number of responses were entered
						If Len(rsSurvey("minimum_number_responses")) > 0 Then
%>
							if (isFirstNumberLarger(<%=rsSurvey("minimum_number_responses")%>, lngNumberEntered) == true) 
							{
								alert("Inserire almeno <%=rsSurvey("minimum_number_responses")%> <% If CLng(rsSurvey("minimum_number_responses")) = 1 Then Response.Write " valore" Else Response.Write " valori" End If %> per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If

						'If a maximum number of responses was specified, make sure that no more than the maximum number of 
						'responses were entered
						If Len(rsSurvey("maximum_number_responses")) > 0 Then
%>
							if (isFirstNumberLarger(lngNumberEntered, <%=rsSurvey("maximum_number_responses")%>) == true) 
							{
								alert("Inserire non più di <%=rsSurvey("maximum_number_responses")%> <% If CLng(rsSurvey("maximum_number_responses")) = 1 Then Response.Write " valore" Else Response.Write " valori" End If %> per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If
					End If
				Case SUR_ITEM_NUMBER:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>				
						if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) == "")
						{
							alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%
					End If

					'Make sure that if a value was entered, it's numeric.
%>
					if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) != "")
					{
						if (isNumeric(trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value)) == false)
						{
							alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
					}
<%					

					'If a minimum value was specified, make sure that the value entered is at least as large as the 
					'minimum value
					If Len(rsSurvey("minimum_value")) > 0 Then
%>
						if (isFirstNumberLarger(<%=rsSurvey("minimum_value")%>, trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value)) == true) 
						{
							alert("Inserire un valore che sia maggiore o uguale a <%=rsSurvey("minimum_value")%> per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%					
					End If

					'If a maximum value was specified, make sure that the value entered is not larger than the 
					'maximum value
					If Len(rsSurvey("maximum_value")) > 0 Then
%>
						if (isFirstNumberLarger(trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value), <%=rsSurvey("maximum_value")%>) == true) 
						{
							alert("Inserire un valore che sia minore o uguale a <%=rsSurvey("maximum_value")%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
						
<%					
					End If
				Case SUR_ITEM_DATE:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>				
						if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) == "")
						{
							alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
						
<%
					End If
%>
					if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) != "")
					{
						if (<%=RenderJSDateValidationRoutineName%>(trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value)) == false)
						{
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
					}
<%				
					'If a minimum date was specified, make sure that the date entered is at least as large as the 
					'minimum date
					If Len(rsSurvey("minimum_value")) > 0 Then
%>
						if (<%=RenderJSIsDateEarlierRoutineName%>('<%=SUR_DATE_DELIMITER%>', trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value), '<%=rsSurvey("minimum_value")%>') == true)
						{
							alert("Please enter a date that is greater than or equal to <%=rsSurvey("minimum_value")%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%					
					End If

					'If a maximum date was specified, make sure that the date entered is not larger than the 
					'maximum date
					If Len(rsSurvey("maximum_value")) > 0 Then
%>
						if (<%=RenderJSIsDateEarlierRoutineName%>('<%=SUR_DATE_DELIMITER%>', '<%=rsSurvey("maximum_value")%>', trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value)) == true)
						{
							alert("Inserire una fata che sia inferiore o uguale a <%=rsSurvey("maximum_value")%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%					
					End If
				Case SUR_ITEM_OPEN_ENDED_ONE_LINE:
					'If the question is required, check to make sure that it was answered
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>				
						if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) == "")
						{
							alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%
					End If

					'If the question is an email address, make sure that if a value was supplied, it's in the
					'correct format.
					If rsSurvey("email_address_yn") = SUR_BOOLEAN_POSITIVE Then
%>				
						if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) != "" && isValidEmailAddress(trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value)) == false)
						{
							alert("Inserire un indirizzo E-mail valido per la domanda numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%
					End If
				Case SUR_ITEM_OPEN_ENDED_COMMENTS_BOX:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
%>				
						if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) == "")
						{
							alert("Inserire un valore per la domanda  numero <%=lngQuestionNumber%>.");
							document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
							return;
						}
<%
					End If
				Case SUR_ITEM_TRUE_FALSE, SUR_ITEM_YES_NO:
					'Only need to check if the question is required
					If rsSurvey("required_yn") = SUR_BOOLEAN_POSITIVE Then
						'If the display format is a combo box, check for the "Please Select" combo value
						If rsSurvey("display_format") = SUR_BOOLEAN_QUESTION_FORMAT_1 Or rsSurvey("display_format") = SUR_BOOLEAN_QUESTION_FORMAT_1 Then
%>				
							if (trim(document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.value) == "<%=SUR_COMBO_PLEASE_SELECT%>")
							{
								alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
								document.forms['frmSurvey'].QID<%=rsSurvey("item_id")%>.focus();
								return;
							}
<%
						Else 'Radio buttons
%> 
							// Dynamically check that required option button question has been answered
							flgValueSelected = false;

							if (document.forms['frmSurvey'] != null) 
							{
							    for (i = 0; i < document.forms['frmSurvey'].length; i++) 
							    {
									if (document.forms['frmSurvey'].elements[i].name == 'QID<%=rsSurvey("item_id")%>')
									{
										if (document.forms['frmSurvey'].elements[i].checked == true)
										{
											flgValueSelected = true;
										}
									}
							    }
							}
							if (flgValueSelected == false)
							{
								alert("Inserire un valore per la domanda numero <%=lngQuestionNumber%>.");
								return;
							}
<%					
						End If
					End If
				Case Else
					'No client-side validation required for all other question types		
			End Select
		End If
				
		'If the item type does not require an answer, do not increment the question number
		If rsSurvey("item_type_id") <> SUR_ITEM_HEADING And rsSurvey("item_type_id") <> SUR_ITEM_HORIZONTAL_RULE And rsSurvey("item_type_id") <> SUR_ITEM_HTML And rsSurvey("item_type_id") <> SUR_ITEM_MESSAGE  And rsSurvey("item_type_id") <> SUR_ITEM_IMAGE Then
			lngQuestionNumber = lngQuestionNumber + 1
		End If
		
		'Set the item ID equal to the current one in the recordset.  The item ID is checked on each iteration to 
		'make sure that the JavaScript is rendered only once per question.
		lngItemID = rsSurvey("item_id")
		rsSurvey.MoveNext
	Loop
	rsSurvey.MoveFirst
%>
	document.forms['frmSurvey'].submit();
}
</script>

<%
	'Reset the question number back to the first question on the page for rendering the actual questions.
	'If the question number is not specified, it's the first question on the first page
	If Len(Request.QueryString("QuestionNumber")) = 0 Then
		lngQuestionNumber = 1
	Else
		lngQuestionNumber = Request.QueryString("QuestionNumber")
	End If

	'Select all of the attributes for the specified template to create the look and feel
	strSQL = "SELECT logo_path, logo_alignment, survey_alignment, display_border_yn, border_color, border_width, survey_background_color, " & _
				"page_background_color, progress_first_color, progress_second_color, survey_name_font_color, " & _
				"survey_name_font_size, survey_name_font_weight, survey_name_font_family, page_title_font_color, " & _
				"page_title_font_size, page_title_font_weight, " & _
				"page_title_font_family, page_number_font_color, page_number_font_size, page_number_font_weight, " & _
				"page_number_font_family, question_text_font_color, question_text_font_size, question_text_font_weight, " & _
				"question_text_font_family, question_subtext_font_color, question_subtext_font_size, " & _
				"question_subtext_font_weight, question_subtext_font_family, navigation_link_font_color, " & _
				"navigation_link_font_size, navigation_link_font_weight, navigation_link_font_family, html_top, html_bottom, " & _
				"navigation_back_button_path, navigation_back_link_text, navigation_next_button_path, navigation_next_link_text, " & _
				"navigation_cancel_button_path, navigation_cancel_link_text, navigation_done_button_path, navigation_done_link_text " & _
			  "FROM sur_template " & _
			  "WHERE template_id = " & lngTemplateID
	rsTemplate.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenForwardOnly, adLockReadOnly, adCmdText
	rsTemplate.MoveFirst

	'Capture all of the fields in local variables
	strLogoPath = rsTemplate("logo_path")
	strLogoAlignment = rsTemplate("logo_alignment")
	strSurveyAlignment = rsTemplate("survey_alignment")
	strDisplayBorderYN = rsTemplate("display_border_yn")
	strBorderColor = rsTemplate("border_color")
	lngBorderWidth = rsTemplate("border_width")
	strSurveyBackgroundColor = rsTemplate("survey_background_color")
	strPageBackgroundColor = rsTemplate("page_background_color")
	strProgressFirstColor = rsTemplate("progress_first_color")
	If Len(strProgressFirstColor) = 0 Or IsNull(strProgressFirstColor) = True Then
		strProgressFirstColor = SUR_DEFAULT_PROGRESS_FIRST_COLOR 
	End If
	strProgressSecondColor = rsTemplate("progress_second_color")
	If Len(strProgressSecondColor) = 0 Or IsNull(strProgressSecondColor) = True Then
		strProgressSecondColor = SUR_DEFAULT_PROGRESS_SECOND_COLOR
	End If
	strHTMLTop = rsTemplate("html_top")
	strHTMLBottom = rsTemplate("html_bottom")
	strNavigationBackButtonPath = rsTemplate("navigation_back_button_path")
	strNavigationBackLinkText = rsTemplate("navigation_back_link_text")
	strNavigationNextButtonPath = rsTemplate("navigation_next_button_path")
	strNavigationNextLinkText = rsTemplate("navigation_next_link_text")
	strNavigationCancelButtonPath = rsTemplate("navigation_cancel_button_path")
	strNavigationCancelLinkText = rsTemplate("navigation_cancel_link_text")
	strNavigationDoneButtonPath = rsTemplate("navigation_done_button_path")
	strNavigationDoneLinkText = rsTemplate("navigation_done_link_text")

	'Render the styles required for the survey	
%>
<style>
	.SurveyBodyStyle
	{
	    FONT-FAMILY: <%=rsTemplate("question_text_font_family")%>;
	    BACKGROUND-COLOR: <%=strPageBackgroundColor%>;
	    COLOR: <%=rsTemplate("question_text_font_color")%>;
<%
		If Len(Trim(strHTMLTop)) > 0 Or Len(Trim(strHTMLBottom)) > 0 Then
%>
		    MARGIN-LEFT: 0;
<%
		ElseIf strDisplayBorderYN = SUR_BOOLEAN_POSITIVE Then
%>
		    MARGIN-LEFT: 10;
<%
		Else
%>
			MARGIN-LEFT: 3;
<%
		End If
%>
	    MARGIN-RIGHT: 0;
	    MARGIN-BOTTOM: 0;
<%
		'If not top HTML was provided, leave a 15-pixel margin at the top; otherwise, flush the survey with the top, 
		'and let the top HTML establish the look and feel.
		If Len(Trim(strHTMLTop)) = 0 Then
%>	    
			MARGIN-TOP: 15;
<%
		Else
%>
			MARGIN-TOP: 0;
<%
		End If
%>
	}

	.Normal
	{
	    COLOR: <% If Len(rsTemplate("question_text_font_color")) > 0 Then Response.Write rsTemplate("question_text_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("question_text_font_family")%>;
	    FONT-SIZE: <% If Len(rsTemplate("question_text_font_size")) > 0 Then Response.Write rsTemplate("question_text_font_size") Else Response.Write "12" End If %>px;
	    FONT-WEIGHT: <%=rsTemplate("question_text_font_weight")%>;
	}

	.Required
	{
	    COLOR: red;
	    FONT-FAMILY: <%=rsTemplate("question_text_font_family")%>;
	    FONT-SIZE: 10px;
	}

	.H1HeadingStyle
	{
	    COLOR: <% If Len(rsTemplate("survey_name_font_color")) > 0 Then Response.Write rsTemplate("survey_name_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("survey_name_font_family")%>;
	    FONT-WEIGHT: <%=rsTemplate("survey_name_font_weight")%>;
	    FONT-SIZE: <% If Len(rsTemplate("survey_name_font_size")) > 0 Then Response.Write rsTemplate("survey_name_font_size") Else Response.Write "18" End If %>px;
	}

	.PageNumberFontStyle
	{
	    COLOR: <% If Len(rsTemplate("page_number_font_color")) > 0 Then Response.Write rsTemplate("page_number_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("page_number_font_family")%>;
	    FONT-WEIGHT: <%=rsTemplate("page_number_font_weight")%>;
	    FONT-SIZE: <% If Len(rsTemplate("page_number_font_size")) > 0 Then Response.Write rsTemplate("page_number_font_size") Else Response.Write "16" End If %>px;
	}

	.InlineHelpSpanStyle
	{
	    COLOR: <% If Len(rsTemplate("question_subtext_font_color")) > 0 Then Response.Write rsTemplate("question_subtext_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("question_subtext_font_family")%>;
	    FONT-SIZE: <% If Len(rsTemplate("question_subtext_font_size")) > 0 Then Response.Write rsTemplate("question_subtext_font_size") Else Response.Write "10" End If %>px;
	    FONT-WEIGHT: <%=rsTemplate("question_subtext_font_weight")%>;
	}

	.SurveyPageTitle
	{
	    COLOR: <% If Len(rsTemplate("page_title_font_color")) > 0 Then Response.Write rsTemplate("page_title_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("page_title_font_family")%>;
	    FONT-SIZE: <% If Len(rsTemplate("page_title_font_size")) > 0 Then Response.Write rsTemplate("page_title_font_size") Else Response.Write "16" End If %>px;
	    FONT-WEIGHT: <%=rsTemplate("page_title_font_weight")%>;
	}

	.QuestionHeadingStyle
	{
	    COLOR: <% If Len(rsTemplate("page_title_font_color")) > 0 Then Response.Write rsTemplate("page_title_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("page_title_font_family")%>;
	    FONT-SIZE: <% If Len(rsTemplate("page_title_font_size")) > 0 Then Response.Write rsTemplate("page_title_font_size") Else Response.Write "16" End If %>px;
	    FONT-WEIGHT: <%=rsTemplate("page_title_font_weight")%>;
	}

	.SurveyNavigationLink A
	{
	    COLOR: <% If Len(rsTemplate("navigation_link_font_color")) > 0 Then Response.Write rsTemplate("navigation_link_font_color") Else Response.Write SUR_DEFAULT_FONT_COLOR End If %>;
	    FONT-FAMILY: <%=rsTemplate("navigation_link_font_family")%>;
	    FONT-SIZE: <% If Len(rsTemplate("navigation_link_font_size")) > 0 Then Response.Write rsTemplate("navigation_link_font_size") Else Response.Write "14" End If %>px;
	    FONT-WEIGHT: <%=rsTemplate("navigation_link_font_weight")%>;
	}
</style>
<%
	'Clean up
	rsTemplate.Close
	Set rsTemplate = Nothing
	
	'Get the page title and page introduction for this page
	strSQL = "SELECT page_title, page_introduction " & _
			 "FROM sur_page " & _
			 "WHERE survey_id = " & lngSurveyID & _
			 " AND page_number = " & lngActualPageNumber
	rsPage.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenForwardOnly, adLockReadOnly, adCmdText
	If rsPage.EOF Then
		strPageTitle = ""	
		strPageIntroduction = ""	
	Else
		rsPage.MoveFirst
		strPageTitle = rsPage("page_title")
		strPageIntroduction = rsPage("page_introduction")
	End If
	rsPage.Close
	Set rsPage = Nothing

%>

<body class="SurveyBodyStyle">
<%
	'If an HTML header was provided, display it
	If Len(strHTMLTop) > 0 Then
		Response.Write strHTMLTop
	End If
%>
<table border="0" cellspacing="0" cellpadding="5" width="760" align="<% If strSurveyAlignment = SUR_SURVEY_ALIGNMENT_CENTER Then Response.Write "center" End If %>">
<%
	'Optionally display a logo at the top of the survey
	If IsNull(strLogoPath) Or Len(strLogoPath) = 0 Then
%>
		<tr>
			<td height="44" valign="bottom">
				<% If strDisplayBorderYN = SUR_BOOLEAN_NEGATIVE Then Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;" End If %><span class="H1HeadingStyle"><a name="skipnav" tabindex="1"><%=strTitle%></a></span>
			</td>
		</tr>
<%	
	Else
		'Whether the image alignment is left or right determines how the image and title are rendered
		If strLogoAlignment = SUR_LOGO_ALIGNMENT_LEFT Then
%>
			<tr>
				<td align="left">
					<img border="0" src="<%=strLogoPath%>" alt="Logo del Questionario">
				</td>
				<td align="right">
					<span class="H1HeadingStyle"><a name="skipnav" tabindex="1"><%=strTitle%></a></span>
				</td>
			</tr>
<%	
		ElseIf strLogoAlignment = SUR_LOGO_ALIGNMENT_RIGHT Then
%>
			<tr>
				<td align="left">
					<span class="H1HeadingStyle"><a name="skipnav" tabindex="1"><%=strTitle%></a></span>
				</td>
				<td align="right">
					<img border="0" src="<%=strLogoPath%>" alt="Logo del Questionario">
				</td>
			</tr>
<%	
		Else
%>
			<tr>
				<td align="left">
					<img border="0" src="<%=strLogoPath%>" alt="Logo del Questionario">
				</td>
			</tr>
			<tr>
				<td align="left">
					<span class="H1HeadingStyle"><a name="skipnav" tabindex="1"><%=strTitle%></a></span>
				</td>
			</tr>
<%	
		End If
	End If
%>	
</table>
<%
	'Optionally display the border
	If strDisplayBorderYN = SUR_BOOLEAN_POSITIVE Then
%>
		<table border="0" style="background-color:<%=strBorderColor%>" cellspacing="0" cellpadding="<%=lngBorderWidth%>" width="760" align="<% If strSurveyAlignment = SUR_SURVEY_ALIGNMENT_CENTER Then Response.Write "center" End If %>"><tr><td>
		<table cellpadding="0" border="0" style="background-color:<%=strSurveyBackgroundColor%>" width="100%"><tr><td>
<%
	Else
%>
		<table border="0" style="background-color:<%=strSurveyBackgroundColor%>" cellspacing="0" cellpadding="0" width="760" align="<% If strSurveyAlignment = SUR_SURVEY_ALIGNMENT_CENTER Then Response.Write "center" End If %>"><tr><td>
<%
	End If
%>
	<table cellpadding="3" cellspacing="2" border="0" width="100%">
<%
		'Only display the page number if a page numbering format was selected
		If rsSurvey("page_numbering_format") <> SUR_PAGE_NUMBERING_DO_NOT_DISPLAY Then
%>
			<tr>
				<td width="28">&nbsp;</td>
				<td align="right" valign="top">
<%		
					'Display the page numbers in the appropriate format
					If rsSurvey("page_numbering_format") = SUR_PAGE_NUMBERING_DISPLAY_PROGRESS Then
%>					
						<span class="PageNumberFontStyle">
							Pagina <%=lngActualPageNumber%> di <%=lngPageCount%>
						</span>
<%
					ElseIf rsSurvey("page_numbering_format") = SUR_PAGE_NUMBERING_DISPLAY_PROGRESS_BAR Then
%>					
						<table width="100" border="0" cellspacing="0" cellpadding="2" height="12">
							<tr>
								<td align="center">
									<span class="Normal">
										Pagina <%=lngActualPageNumber%> di <%=lngPageCount%>
									</span>
								</td>
							</tr>
						</table>
						<table width="100" border="0" cellspacing="0" cellpadding="1" height="12">
							<tr>
								<td bgcolor="black">
									<table width="100" border="0" cellspacing="0" cellpadding="0" height="12">
										<tr> 
											<td width="<%=CInt((lngActualPageNumber / lngPageCount ) * 100)%>" bgcolor="<%=strProgressFirstColor%>"></td>
											<td width="<%=CInt((100 - ((lngActualPageNumber / lngPageCount ) * 100)))%>" bgcolor="<%=strProgressSecondColor%>"></td>
										</tr>
									</table>
								</td>
							</tr>
						</table>
						
<%
					Else 'SUR_PAGE_NUMBERING_DISPLAY_PAGE_NUMBER_ONLY
%>					
						<span class="PageNumberFontStyle">
							Pagina <%=lngActualPageNumber%>
						</span>
<%
					End If
%>					
				</td>
				<td width="14">&nbsp;</td>
			</tr>
<%
		Else
%>
			<tr><td colspan="3"><br></td></tr>
<%
		End If
		
		'Only display the page title if there is one
		If Len(strPageTitle) > 0 Then
%>
			<tr>
				<td width="28" rowspan="5">&nbsp;</td>
				<td>
					<span class="SurveyPageTitle">
						<%=strPageTitle%>
					</span>
				</td>
				<td width="14" rowspan="5">&nbsp;</td>
			</tr>
<%
		End If
		
		'Only display the page introduction if there is one
		If Len(strPageIntroduction) > 0 Then
%>
			<tr>
				<td align="left" valign="top">
					<span class="Normal"><%=strPageIntroduction%></span>
				</td>
			</tr>
<%
		End If
%>
	</table>
	<br>
<%
	If Request.Form("AdminOrOwnerEditResponse") = SUR_BOOLEAN_POSITIVE_DISPLAY Or Request.QueryString("Edit") = SUR_BOOLEAN_POSITIVE_DISPLAY Then
		strEditValue = SUR_BOOLEAN_POSITIVE_DISPLAY
	Else
		strEditValue = SUR_BOOLEAN_NEGATIVE_DISPLAY
	End If
%>	
	<table cellpadding="2" cellspacing="0" border="0" width="100%" height="200">
		<form action="TakeSurveyAction.asp?DisplayHeader=<%=Request.QueryString("DisplayHeader")%>" method="post" name="frmSurvey">
			<input type="hidden" value="<%=strEditValue%>" name="AdminOrOwnerEditResponse">
			<input type="hidden" value="<%=lngResponseID%>" name="AdminOrOwnerResponseID">
			<input type="hidden" value="<%=EncryptSurveyID(lngSurveyID)%>" name="SurveyID">
			<input type="hidden" value="<%=lngEmailAddressID%>" name="EmailAddressID">
			<input type="hidden" value="<%=lngEmailMessageID%>" name="EmailMessageID">
			<input type="hidden" value="<%=Request.QueryString("EID")%>" name="EID">
			<input type="hidden" value="<%=strResponseType%>" name="ResponseType">
<%
			If InStr(Request.ServerVariables("QUERY_STRING"), "ItemID") > 0 Then
				For Each strTempValue In Request.Querystring
					If Left(strTempValue, 6) = "ItemID" Then
						strItemIDValues = strItemIDValues & strTempValue & "=" & Request.Querystring(strTempValue) & "&"
					End If
				Next
			Else
				strItemIDValues = ""
			End If
%>
			<input type="hidden" value="<%=strItemIDValues%>" name="ItemIDValues">
			<input type="hidden" value="<%=Request.ServerVariables("QUERY_STRING")%>" name="PostedQueryString">
			<input type="hidden" value="<%=lngDisplayPageNumber%>" name="DisplayPageNumber">
<%
			If SUR_DATABASE_TYPE = "SQLServer" Or SUR_DATABASE_TYPE = "MySQL" Then
				strTempDate = Year(Now()) & SUR_DATE_DELIMITER & Month(Now()) & SUR_DATE_DELIMITER & Day(Now())
			Else
				If SUR_DATE_FORMAT = SUR_DATE_FORMAT_AMERICAN Then
					strTempDate = Month(Now()) & SUR_DATE_DELIMITER & Day(Now()) & SUR_DATE_DELIMITER & Year(Now())
				Else 'SUR_DATE_FORMAT_EUROPEAN
					strTempDate = Day(Now()) & SUR_DATE_DELIMITER & Month(Now()) & SUR_DATE_DELIMITER & Year(Now())
				End If
			End If
%>
			<input type="hidden" value="<%=strTempDate & " " & DisplayCurrentTime()%>" name="ResponseStartDate">
			<input type="hidden" value="<%=lngActualPageNumber%>" name="ActualPageNumber">
			<input type="hidden" value="<% If flgUpdatingSurvey = True Then Response.Write("True") Else Response.Write("False") End If %>" name="hdnUpdatingSurvey">
<%
			'Add a value to SESSION indicating the survey and page number the user is about to take.  On the "action"
			'page for this survey, check this value again to make sure that the same page is not submitted twice.
			Session(SUR_UNIQUE_RESPONSE_IDENTIFIER) = CStr(lngSurveyID) & CStr(lngActualPageNumber)
			
			strQuestionNumberingFormat = rsSurvey("question_numbering_format")	
			Do While Not rsSurvey.EOF
%>
				<tr>
					<td width="10">&nbsp;</td>
					<td valign="top">
					<%DisplayFormattedItem rsSurvey, flgUpdatingSurvey, True%>
					</td>
					<td width="10">&nbsp;</td>
				</tr>
				<tr>
					<td colspan="3">&nbsp;</td>
				</tr>
<%	
				rsSurvey.MoveNext
			Loop

			'If the question numbering format is within each page, update the next question number to 1, since that is
			'the number each page will always start with.  Otherwise, leave the variable lngQuestionNumber as is, which 
			'will cause the next page to be started with the subsequent number in the sequence.
			If strQuestionNumberingFormat = SUR_QUESTION_NUMBERING_EACH_PAGE Then
				lngQuestionNumber = 1
			End If
%>			
			<input type="hidden" value="<%=lngResponseID%>" name="ResponseID">
			<input type="hidden" value="<%=lngQuestionNumber%>" name="QuestionNumber">
		</form>
	</table>

	<table border="0" cellpadding="10" cellspacing="3" width="100%">
		<tr>
			<td width="25">&nbsp;</td>
			<td align="center">
<%
				'Display the back button on all but the first page, but only if the back button should be displayed, 
				'based on the settings for the survey.
				If lngActualPageNumber <> 1 And strBackButtonDisplay = SUR_BACK_BUTTON_DISPLAY Then
					'Use the button for the Back button, if provided
					If Len(strNavigationBackButtonPath) > 0 Then
						'Use the link text for the Back button, if provided
						If Len(strNavigationBackButtonPath) > 0 Then
%>
							<a href="javascript:window.history.back();"><img border="0" alt="Indietro" name="btnBack" src="<%=strNavigationBackButtonPath%>"></a>&nbsp;&nbsp;
<%
						Else
%>
							<a href="javascript:window.history.back();"><img border="0" alt="Indietro" name="btnBack" src="Resources/SurveyButtons/Back.gif"></a>&nbsp;&nbsp;
<%
						End If					
					Else
%>
						<span class="SurveyNavigationLink">
							<a href="TakeSurvey.asp?DisplayHeader=<%Request.QueryString("DisplayHeader")%>&SurveyID=<%=EncryptSurveyID(lngSurveyID)%>&ActualPageNumber=<%=Request.QueryString("PreviousActualPageNumber")%>&DisplayPageNumber=<%=Request.QueryString("PreviousDisplayPageNumber")%>&ResponseID=<%=lngResponseID%>&QuestionNumber=<%=Request.QueryString("PreviousQuestionNumber")%>&Edit=Yes"><%=strNavigationBackLinkText%></a>
			&nbsp;&nbsp;
						</span>
<%
					End If
				End If

				'If this is the last page, display a "Done" button; otherwise, display a "Next" button.
				If CLng(lngPageCount) = CLng(lngActualPageNumber) Then
					'Use the button for the Next button, if provided
					If Len(strNavigationDoneButtonPath) > 0 Then
						'Use the button path provided, if there is one; otherwise, use the default button
						If Len(strNavigationDoneButtonPath) > 0 Then
%>
							<a href="javascript:submitCheck();"><img border="0" alt="Completa" name="btnDone" src="<%=strNavigationDoneButtonPath%>"></a>&nbsp;&nbsp;
<%
						Else
%>
							<a href="javascript:submitCheck();"><img border="0" alt="Completa" name="btnDone" src="Resources/SurveyButtons/Done.gif"></a>&nbsp;&nbsp;
<%
						End If					
					Else
%>
						<span class="SurveyNavigationLink">
							<a href="javascript:submitCheck();"><%=strNavigationDoneLinkText%></a>
			&nbsp;&nbsp;
						</span>
<%
					End If
				Else
					'Use the button for the Next button, if provided
					If Len(strNavigationNextButtonPath) > 0 Then
						'Use the button path provided, if there is one; otherwise, use the default button
						If Len(strNavigationNextButtonPath) > 0 Then
%>
							<a href="javascript:submitCheck();"><img border="0" alt="Successiva" name="btnNext" src="<%=strNavigationNextButtonPath%>"></a>&nbsp;&nbsp;
<%
						Else
%>
							<a href="javascript:submitCheck();"><img border="0" alt="Successiva" name="btnNext" src="Resources/SurveyButtons/Next.gif"></a>&nbsp;&nbsp;
<%
						End If					
					Else
%>
						<span class="SurveyNavigationLink">
							<a href="javascript:submitCheck();"><%=strNavigationNextLinkText%></a>
			&nbsp;&nbsp;
						</span>
<%
					End If
				End If

				'Only display the Cancel button if it was not explicitly set to "Do not display"
				If strCancelButtonDisplay <> SUR_CANCEL_BUTTON_DO_NOT_DISPLAY Then
					'If the button was provided for the Cancel button, use that first
					If Len(strNavigationCancelButtonPath) > 0 Then
						'Use the button path provided, if there is one; otherwise, use the default button
						If Len(strNavigationCancelButtonPath) > 0 Then
							strButtonPath = strNavigationCancelButtonPath
						Else
							strButtonPath = "Resources/SurveyButtons/Cancel.gif"
						End If
						
						'Set the appropriate action, based on the survey options, for what to do if a user clicks the Cancel button
						If strCancelButtonDisplay = SUR_CANCEL_BUTTON_CLOSE Then
%>
							<img onClick="javascript:window.close();" style="cursor:hand" border="0" alt="Annulla" name="btnCancel" src="<%=strButtonPath%>">&nbsp;&nbsp;
<%
						Else
							'Redirecting, so set a variable equal to the URL to redirect to
							If strCancelButtonDisplay = SUR_CANCEL_BUTTON_END_OF_SURVEY Then
								strRedirectURL = "TakeSurveyActionComplete.asp?SurveyID=" & EncryptSurveyID(lngSurveyID)
							Else 'SUR_CANCEL_BUTTON_REDIRECT
								strRedirectURL = strCancelButtonRedirectURL
							End If
%>
							<a href="<%=strRedirectURL%>"><img border="0" alt="Annulla" name="btnCancel" src="<%=strButtonPath%>"></a>&nbsp;&nbsp;
<%
						End If
					Else
						'Set the appropriate action for the Cancel button
						If strCancelButtonDisplay = SUR_CANCEL_BUTTON_CLOSE Then
							strRedirectURL = "javascript:window.close();"
						ElseIf strCancelButtonDisplay = SUR_CANCEL_BUTTON_END_OF_SURVEY Then
							strRedirectURL = "TakeSurveyActionComplete.asp?SurveyID=" & EncryptSurveyID(lngSurveyID)
						Else 'SUR_CANCEL_BUTTON_REDIRECT
							strRedirectURL = strCancelButtonRedirectURL
						End If
%>
						<span class="SurveyNavigationLink">
							<a href="<%=strRedirectURL%>"><%=strNavigationCancelLinkText%></a>
			&nbsp;&nbsp;
						</span>
<%
					End If
				End If
%>					
			</td>
			<td width="10">&nbsp;</td>
		</tr>
	</table>
	
<%
	'If the border was displayed, close out an extra table
	If strDisplayBorderYN = SUR_BOOLEAN_POSITIVE Then
%>
		</td></tr></table>
<%
	End If
%>	
</td></tr></table>
<%
	'If an HTML footer was provided, display it
	If Len(strHTMLBottom) > 0 Then
		Response.Write strHTMLBottom
	Else
		Response.Write "<br>"
	End If
%>
</body>
</html>
<%
	'Clean up
	rsSurvey.Close
	Set rsSurvey = Nothing

	'Ensure that the web server returns the page
	Response.Flush
%>